-
Notifications
You must be signed in to change notification settings - Fork 2
/
build.gradle.kts
132 lines (116 loc) · 3.54 KB
/
build.gradle.kts
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
/*
* Copyright (c) 2021. Christian Grach <christian.grach@cmgapps.com>
*
* SPDX-License-Identifier: Apache-2.0
*/
@file:Suppress("UnstableApiUsage")
import com.cmgapps.gradle.curriculumvitae.configProperty
import com.cmgapps.gradle.curriculumvitae.javaLanguageVersion
import java.util.Properties
plugins {
id("curriculumvitae.test")
id("com.google.cloud.tools.appengine")
alias(libs.plugins.kotlin.serialization)
alias(libs.plugins.markdown)
id("ktlint")
application
alias(libs.plugins.shadowJar)
alias(libs.plugins.buildConfig)
}
group = "com.cmgapps.ktor"
version = libs.versions.versionName.get()
application {
mainClass.set("io.ktor.server.netty.EngineMain")
applicationDefaultJvmArgs = listOf("-Dio.ktor.development=true")
}
appengine {
val localPropsFile = rootDir.resolve("local.properties")
val localProperties = if (localPropsFile.exists()) {
Properties().apply {
localPropsFile.inputStream().use {
load(it)
}
}
} else {
null
}
tools {
if (localProperties?.containsKey("gcloud.sdk.dir") == true) {
setCloudSdkHome(localProperties["gcloud.sdk.dir"])
}
}
stage {
setArtifact(
provider {
tasks.shadowJar.get().outputs.files.singleFile
},
)
}
deploy {
if (localProperties?.containsKey("gcloud.project.id") == true) {
projectId = localProperties.getProperty("gcloud.project.id")
}
version = libs.versions.backendVersion.get()
}
}
kotlin {
jvmToolchain {
languageVersion.set(javaLanguageVersion)
}
}
tasks {
htmlToMarkdown {
sourceDir = sourceSets.test.get().resources.sourceDirectories.singleFile
configuration = mapOf("tables" to true)
doLast {
copy {
from(outputDir)
include("root.md")
into(projectDir)
rename {
"README.md"
}
}
}
}
}
buildConfig {
packageName("com.cmgapps.ktor.curriculumvitae")
buildConfigField(
"com.cmgapps.ktor.curriculumvitae.infra.model.ApiInfo",
"apiInfo",
provider {
val email by configProperty
val name by configProperty
val version = libs.versions.backendVersion.get()
val serverProductionUrl by configProperty
val serverProductionDescription by configProperty
"""ApiInfo(
version = "$version",
contactName = "$name",
contactEmail = "$email",
serverUrl = "$serverProductionUrl",
serverDescription = "$serverProductionDescription"
)"""
},
)
}
dependencies {
implementation(projects.common)
implementation(kotlin("stdlib-jdk8", libs.versions.kotlin.get()))
implementation(libs.bundles.ktor.server)
implementation(libs.kotlinCss)
implementation(libs.logback.classic)
implementation(libs.kotlinx.serialization.json)
implementation(libs.kotlinx.datetime)
implementation(libs.bundles.koin.server)
implementation(libs.sqldelight.driver.jvm)
implementation(libs.swaggerUi)
implementation(libs.jsonSchema.generator)
testImplementation(libs.ktor.testing)
testImplementation(platform(libs.junit.bom))
testImplementation("org.junit.jupiter:junit-jupiter")
testImplementation(libs.hamcrest)
testImplementation(libs.mockito.jupiter)
testImplementation(libs.mockito.kotlin)
}