[NixOS] [General] Provide option to build patched wlroots with hardware cursor support for NVIDIA and VmWare

[VeilSilence]

Greetings.

As the title says, currently Nvidia/VmWare users don't have hardware cursor support.
However, it's about to change ( soon? ) I think: https://gitlab.freedesktop.org/wlroots/wlroots/-/merge_requests/4596
It's unclear when it's going to be merged upstream, but people report that it fixes cursor for them already.

As new NixOS user, i'm not quiet sure how to test them atm. My guess is should be something like that?
nix/wlroots.nix

{
  version,
  src,
  wlroots,
  enableXWayland ? true,
}:
wlroots.overrideAttrs (old: {
  inherit version src enableXWayland;

  pname = "${old.pname}-hyprland";

  patches = [
    ./patch1.patch
    ./patch2.patch
  ] 
})

[fufexan]

Something like that, you can do this instead:

{pkgs, inputs, ...}:
# ...
inputs.hyprland.packages.${pkgs.system}.hyprland.override {
  wlroots = inputs.hyprland.packages.${pkgs.system}.wlroots-hyprland.overrideAttrs (self: super: {
    patches = (super.patches or []) ++ [
      (pkgs.fetchPatch {
        url = "https://gitlab.freedesktop.org/wlroots/wlroots/-/merge_requests/4596.patch";
        hash = "";
      })
    ];
  };
};

Make sure to replace the hash with the one given by nix.

[VeilSilence]

Make sure to replace the hash with the one given by nix.

Configuration.nix

{pkgs, inputs, ...}:
# ...
 # Hyprland flake
  programs.hyprland = {
    enable = true;
    package = inputs.hyprland.packages.${pkgs.system}.hyprland;
    inputs.hyprland.packages.${pkgs.system}.hyprland.override = {
      wlroots = inputs.hyprland.packages.${pkgs.system}.wlroots-hyprland.overrideAttrs (self: super: {
        patches =
          (super.patches or [])
          ++ [
            (pkgs.fetchPatch {
              url = "https://gitlab.freedesktop.org/wlroots/wlroots/-/merge_requests/4596.patch";
              hash = "";
            })
          ];
      });
    };
  };

My first attempt to insert your override ( copy paste ) into my configuration nix. Failed as expected.

Errors

/etc/nixos🔒 ❯ sudo nixos-rebuild switch --flake . --show-trace
error:
       … while calling the 'seq' builtin

         at /nix/store/cb1gs888vfqxawvc65q1dk6jzbayh3wz-source/lib/modules.nix:322:18:

          321|         options = checked options;
          322|         config = checked (removeAttrs config [ "_module" ]);
             |                  ^
          323|         _module = checked (config._module);

       … while calling the 'throw' builtin

         at /nix/store/cb1gs888vfqxawvc65q1dk6jzbayh3wz-source/lib/modules.nix:298:18:

          297|                     ''
          298|             else throw baseMsg
             |                  ^
          299|         else null;

       error: The option `programs.hyprland.inputs' does not exist. Definition values:
       - In `/nix/store/hmb989rdvhghjf6py3fq4qsrwdcvb3vj-source/configuration.nix':
           {
             hyprland = {
               packages = {
                 x86_64-linux = {
                   hyprland = {

After a couple of attempts and some "shaman singing and dancing with a drums", my final result is:

Configuration.nix

{pkgs, inputs, ...}:
# ...
  # Hyprland flake + hardware cursor fix
  programs.hyprland = {
    enable = true;
    package = inputs.hyprland.packages.${pkgs.system}.hyprland.override {
      wlroots = inputs.hyprland.packages.${pkgs.system}.wlroots-hyprland.overrideAttrs (self: super: {
        patches =
          (super.patches or [])
          ++ [
            (pkgs.fetchpatch {
              url = "https://gitlab.freedesktop.org/wlroots/wlroots/-/merge_requests/4596.patch";
              hash = "sha256-apLXjGfGHgY5gY2/9WG66ngMPoshiSI0uSkZ3Gisdzo=";
            })
          ];
      });
    };
  };

And it works. Finally, the hardware cursor are functioning.
Hyprland commit at 77f2699 as expected.
Thank you for assistance with this. If there something that need to be changed in this override, let me know.

[Serpentian]

@fufexan since there's no wlroots-hyprland in hyprland.packages.${pkgs.system} anymore is there any way to apply patches on top of wlroots on the current version of Hyprland?

[Serpentian]

The build fails with error: error: function 'anonymous lambda' called with unexpected argument 'wlroots'.

I managed to apply patch to wlroots only on 0.38.0. All consequent versions doesn't work for me:

inputs = {
        hyprland = {
            type = "git";
            url = "https://github.com/hyprwm/Hyprland";
            rev = "3875679755014997776e091ff8903acfb311dd2f"; # 0.38.0
            submodules = true;
        };
};

[fufexan]

Should work if you add a patch that adds a patch (sounds weird, I know). Or you can do something like this

hyprland.package = let
  patch = pkgs.fetchpatch {
    url = "your-url-here";
    name = "patch-name.patch";
    hash = "";
  };
in
inputs.hyprland.packages.${pkgs.system}.default.overrideAttrs (self: super: {
  postUnpack = ''
    cp ${patch} subprojects/wlroots-hyprland/patches
  '';
});

[Serpentian]

Thank you a lot! The only note, that $sourceRoot should be added for this to work:

    programs.hyprland.package = let
      patch = ./displaylink-custom.patch;
    in
    inputs.hyprland.packages.${pkgs.system}.default.overrideAttrs (self: super: {
      postUnpack = ''
        cp ${patch} $sourceRoot/subprojects/wlroots-hyprland/patches
      '';
    });

[fufexan]

Oh right, that might be a caveat of the unpackPhase. Should work without it starting from patchPhase (not sure if pre as well).