-
Notifications
You must be signed in to change notification settings - Fork 5
/
mo_linfit.f90
318 lines (272 loc) · 10.8 KB
/
mo_linfit.f90
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
!> \file mo_linfit.f90
!> \brief Fitting a straight line.
!> \details This module provides a routine to fit a straight line with model I or model II regression.
!> \authors Matthias Cuntz
!> \date Mar 2011
MODULE mo_linfit
! This module provides a routine to fit a straight line with model I or model II regression.
! Written Matthias Cuntz, Mar 2011
! License
! -------
! This file is part of the JAMS Fortran package, distributed under the MIT License.
!
! Copyright (c) 2011 Matthias Cuntz - mc (at) macu (dot) de
!
! Permission is hereby granted, free of charge, to any person obtaining a copy
! of this software and associated documentation files (the "Software"), to deal
! in the Software without restriction, including without limitation the rights
! to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
! copies of the Software, and to permit persons to whom the Software is
! furnished to do so, subject to the following conditions:
!
! The above copyright notice and this permission notice shall be included in all
! copies or substantial portions of the Software.
!
! THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
! IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
! FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
! AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
! LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
! OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
! SOFTWARE.
USE mo_kind, ONLY: sp, dp
Implicit NONE
PUBLIC :: linfit ! Fitting straight line (without error bars on input), Model I or Model II
! ------------------------------------------------------------------
! NAME
! linfit
! PURPOSE
!> \brief Fits a straight line to input data by minimizing chi^2.
!> \details Given a set of data points x(1:ndata), y(1:ndata),
!> fit them to a straight line \f$ y = a+bx \f$ by minimizing chi2.\n
!> Model I minimizes y vs. x while Model II takes the geometric mean of y vs. x and x vs. y.
!> Returned is the fitted line at x.
!> Optional returns are a, b and their respective probable uncertainties siga and sigb,
!> and the chi-square chi2.
! CALLING SEQUENCE
! out = linfit(x, y, a=a, b=b, siga=siga, sigb=sigb, chi2=chi2, model2=model2)
! INTENT(IN)
!> \param[in] "real(sp/dp) :: x(:)" 1D-array with input x
!> \param[in] "real(sp/dp) :: y(:)" 1D-array with input y
! INTENT(INOUT)
! None
! INTENT(OUT)
! None
! INTENT(IN), OPTIONAL
!> \param[in] "logical, optional :: model2" If present, use geometric mean regression
!> instead of ordinary least square
! INTENT(INOUT), OPTIONAL
! None
! INTENT(OUT), OPTIONAL
!> \param[out] "real(sp/dp), dimension(M) :: a" intercept
!> \param[out] "real(sp/dp), dimension(M) :: b" slope
!> \param[out] "real(sp/dp), dimension(M) :: siga" error on intercept
!> \param[out] "real(sp/dp), dimension(M) :: sigb" error on slope
!> \param[out] "real(sp/dp) :: chisq" Minimum chi^2
! RETURN
!> \return real(sp/dp), dimension(:), allocatable :: out — fitted values at x(:).
! RESTRICTIONS
! None
! EXAMPLE
! ytmp = linfit(x, y, a=inter, b=slope, model2=.true.)
! LITERATURE
! Model I follows closely
! Press WH, Teukolsky SA, Vetterling WT, & Flannery BP - Numerical Recipes in Fortran 90 -
! The Art of Parallel Scientific Computing, 2nd Edition, Volume 2 of Fortran Numerical Recipes,
! Cambridge University Press, UK, 1996
! For Model II (geometric mean regression)
! Robert R. Sokal and F. James Rohlf, Biometry: the principle and practice of statistics
! in biological research, Freeman & Co., ISBN 0-7167-2411-1
! HISTORY
! Written Matthias Cuntz, March 2011 - following closely the routine fit of Numerical Recipes
! - linfit Model II: geometric mean regression
! Modified Matthias Cuntz, Nov 2011 - sp, dp
! - documentation
INTERFACE linfit
MODULE PROCEDURE linfit_sp, linfit_dp
END INTERFACE linfit
! ------------------------------------------------------------------
PRIVATE
! ------------------------------------------------------------------
CONTAINS
! ------------------------------------------------------------------
FUNCTION linfit_dp(x, y, a, b, siga, sigb, chi2, model2)
IMPLICIT NONE
REAL(dp), DIMENSION(:), INTENT(IN) :: x, y
REAL(dp), OPTIONAL, INTENT(OUT) :: a, b, siga, sigb, chi2
LOGICAL , OPTIONAL, INTENT(IN) :: model2
#ifndef __PYTHON__
REAL(dp), DIMENSION(:), allocatable :: linfit_dp
#else
REAL(dp), DIMENSION(size(x)) :: linfit_dp
#endif
REAL(dp) :: sigdat, nx, sx, sxoss, sy, st2
REAL(dp), DIMENSION(size(x)), TARGET :: t
REAL(dp) :: aa, bb, cchi2
LOGICAL :: mod2
REAL(dp) :: mx, my, sx2, sy2, sxy, sxy2, syx2, ssigb
!REAL(dp) :: r
if (size(x) /= size(y)) stop 'linfit_dp: size(x) /= size(y)'
#ifndef __PYTHON__
if (.not. allocated(linfit_dp)) allocate(linfit_dp(size(x)))
#endif
if (present(model2)) then
mod2 = model2
else
mod2 = .false.
endif
if (mod2) then
nx = real(size(x),dp)
mx = sum(x)/nx
my = sum(y)/nx
sx2 = sum((x-mx)*(x-mx))
sy2 = sum((y-my)*(y-my))
sxy = sum((x-mx)*(y-my))
!r = sxy / sqrt(sx2) / sqrt(sy2)
bb = sign(sqrt(sy2/sx2),sxy)
aa = my - bb*mx
linfit_dp(:) = aa + bb*x(:)
if (present(a)) a = aa
if (present(b)) b = bb
if (present(chi2)) then
t(:) = y(:)-linfit_dp(:)
chi2 = dot_product(t,t)
endif
if (present(siga) .or. present(sigb)) then
syx2 = (sy2 - sxy*sxy/sx2) / (nx-2.0_dp)
sxy2 = (sx2 - sxy*sxy/sy2) / (nx-2.0_dp)
! syx2 should be >0
! ssigb = sqrt(syx2/sx2)
ssigb = sqrt(abs(syx2)/sx2)
if (present(sigb)) sigb = ssigb
if (present(siga)) then
! siga = sqrt(syx2*(1.0_dp/nX+mx*mx/sx2))
siga = sqrt(abs(syx2)*(1.0_dp/nX+mx*mx/sx2))
! Add Extra Term for Error in xmean which is not in Sokal & Rohlf.
! They take the error estimate of the chi-squared error for a.
! siga = sqrt(siga*siga + bb*bb*sxy2/nx)
siga = sqrt(siga*siga + bb*bb*abs(sxy2)/nx)
endif
endif
else
nx = real(size(x),dp)
sx = sum(x)
sy = sum(y)
sxoss = sx/nx
t(:) = x(:)-sxoss
bb = dot_product(t,y)
st2 = dot_product(t,t)
bb = bb/st2
aa = (sy-sx*bb)/nx
linfit_dp(:) = aa + bb*x(:)
if (present(a)) a = aa
if (present(b)) b = bb
if (present(chi2) .or. present(siga) .or. present(sigb)) then
t(:) = y(:)-linfit_dp(:)
cchi2 = dot_product(t,t)
if (present(chi2)) chi2 = cchi2
if (present(siga) .or. present(sigb)) then
sigdat = sqrt(cchi2/(size(x)-2))
if (present(siga)) then
siga = sqrt((1.0_dp+sx*sx/(nx*st2))/nx)
siga = siga*sigdat
endif
if (present(sigb)) then
sigb = sqrt(1.0_dp/st2)
sigb = sigb*sigdat
endif
endif
endif
endif
END FUNCTION linfit_dp
FUNCTION linfit_sp(x, y, a, b, siga, sigb, chi2, model2)
IMPLICIT NONE
REAL(sp), DIMENSION(:), INTENT(IN) :: x, y
REAL(sp), OPTIONAL, INTENT(OUT) :: a, b, siga, sigb, chi2
LOGICAL , OPTIONAL, INTENT(IN) :: model2
#ifndef __PYTHON__
REAL(sp), DIMENSION(:), allocatable :: linfit_sp
#else
REAL(sp), DIMENSION(size(x)) :: linfit_sp
#endif
REAL(sp) :: sigdat, nx, sx, sxoss, sy, st2
REAL(sp), DIMENSION(size(x)), TARGET :: t
REAL(sp) :: aa, bb, cchi2
LOGICAL :: mod2
REAL(sp) :: mx, my, sx2, sy2, sxy, sxy2, syx2, ssigb
!REAL(sp) :: r
if (size(x) /= size(y)) stop 'linfit_sp: size(x) /= size(y)'
#ifndef __PYTHON__
if (.not. allocated(linfit_sp)) allocate(linfit_sp(size(x)))
#endif
if (present(model2)) then
mod2 = model2
else
mod2 = .false.
endif
if (mod2) then
nx = real(size(x),sp)
mx = sum(x)/nx
my = sum(y)/nx
sx2 = sum((x-mx)*(x-mx))
sy2 = sum((y-my)*(y-my))
sxy = sum((x-mx)*(y-my))
!r = sxy / sqrt(sx2) / sqrt(sy2)
bb = sign(sqrt(sy2/sx2),sxy)
aa = my - bb*mx
linfit_sp(:) = aa + bb*x(:)
if (present(a)) a = aa
if (present(b)) b = bb
if (present(chi2)) then
t(:) = y(:)-linfit_sp(:)
chi2 = dot_product(t,t)
endif
if (present(siga) .or. present(sigb)) then
syx2 = (sy2 - sxy*sxy/sx2) / (nx-2.0_sp)
sxy2 = (sx2 - sxy*sxy/sy2) / (nx-2.0_sp)
! syx2 should be >0
! ssigb = sqrt(syx2/sx2)
ssigb = sqrt(abs(syx2)/sx2)
if (present(sigb)) sigb = ssigb
if (present(siga)) then
! siga = sqrt(syx2*(1.0_sp/nX+mx*mx/sx2))
siga = sqrt(abs(syx2)*(1.0_sp/nX+mx*mx/sx2))
! Add Extra Term for Error in xmean which is not in Sokal & Rohlf.
! They take the error estimate of the chi-squared error for a.
! siga = sqrt(siga*siga + bb*bb*sxy2/nx)
siga = sqrt(siga*siga + bb*bb*abs(sxy2)/nx)
endif
endif
else
nx = real(size(x),sp)
sx = sum(x)
sy = sum(y)
sxoss = sx/nx
t(:) = x(:)-sxoss
bb = dot_product(t,y)
st2 = dot_product(t,t)
bb = bb/st2
aa = (sy-sx*bb)/nx
linfit_sp(:) = aa + bb*x(:)
if (present(a)) a = aa
if (present(b)) b = bb
if (present(chi2) .or. present(siga) .or. present(sigb)) then
t(:) = y(:)-linfit_sp(:)
cchi2 = dot_product(t,t)
if (present(chi2)) chi2 = cchi2
if (present(siga) .or. present(sigb)) then
sigdat = sqrt(cchi2/(size(x)-2))
if (present(siga)) then
siga = sqrt((1.0_sp+sx*sx/(nx*st2))/nx)
siga = siga*sigdat
endif
if (present(sigb)) then
sigb = sqrt(1.0_sp/st2)
sigb = sigb*sigdat
endif
endif
endif
endif
END FUNCTION linfit_sp
! ------------------------------------------------------------------
END MODULE mo_linfit