-
Notifications
You must be signed in to change notification settings - Fork 9
/
kernel.ld.in
120 lines (103 loc) · 3.18 KB
/
kernel.ld.in
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
/* fwx.ld */
INCLUDE BUILDDIR/layout.ld
_estack = _kern_init_msp_stack;
/* Define output sections */
SECTIONS
{
/* The startup code goes first into FLASH */
.isr_vector :
{
. = ALIGN(4);
KEEP(*(.isr_vector)) /* Startup code */
. = ALIGN(4);
}>FLASHMAP_KERN
/* The program code and other data goes into FLASH */
.text :
{
_stext = .; /* create a global symbol at data start */
*startup*(.text.Reset_Handler)
*(.text*)
*(.rodata) /* .rodata sections (constants, strings, etc.) */
*(.rodata*) /* .rodata sections (constants, strings, etc.) */
*(.glue_7) /* glue arm to thumb code */
*(.glue_7t) /* glue thumb to arm code */
*(.eh_frame)
KEEP (*(.init))
KEEP (*(.fini))
. = ALIGN(4);
_etext = .; /* define a global symbols at end of code */
_exit = .;
_sigot = .;
}>FLASHMAP_KERN
/* used by the startup to initialize got */
.got : AT ( _sigot ) {
. = ALIGN(4);
_sgot = .;
/* *(.got.plt)
* We don't need plt segment
* since we do not need dynamic library relocation
*/
*(.got)
*(.got*)
. = ALIGN(4);
_egot = .;
/* used by the startup to initialize data */
_sidata = .;
}>FLASHMAP_KERN
/* used by the startup to initialize data */
/* Initialized data sections goes into RAM, load LMA copy after code */
.data : AT ( _sidata )
{
. = ALIGN(4);
_sdata = .; /* create a global symbol at data start */
*(.data) /* .data sections */
*(.data*) /* .data* sections */
_edata = .; /* define a global symbol at data end */
}>RAM_KERN
.data_in_flash : AT ( _sidata )
{
/* to be sure that there is enough space in flash for .data, we fill the
* content with .data size here. .data is added in a dedicated section
* using the AT attribute
* This section doesn't store anything but fullfill the flash with
* the size of .data section */
. = . + SIZEOF(.data);
. = ALIGN(4);
}>FLASHMAP_KERN
/* Uninitialized data section */
. = ALIGN(4);
.bss :
{
/* This is used by the startup in order to initialize the .bss section */
_sbss = .; /* define a global symbol at bss start */
__bss_start__ = _sbss;
*debug.o(.bss)
*(.bss)
*(.bss*)
*(COMMON)
. = ALIGN(4);
_ebss = .; /* define a global symbol at bss end */
__bss_end__ = _ebss;
}>RAM_KERN
/* heap_stack section, used to check that there is enough RAM left */
._heap_stack :
{
. = ALIGN(4);
PROVIDE ( end = . );
PROVIDE ( _end = . );
. = . + 4096; /* kernel idle thread stack */
. = . + 4096; /* softirq thread stack */
. = . + 4096; /* user ISR stack (remapped region) */
. = . + 4096; /* kernel initial transient stack is not counted as it
is used only at early boot. We just give little space
to avoid .data+.bss collision with this stack at boot
time */
_kern_init_msp_stack = .;
. = ALIGN(4);
}>RAM_KERN
/* Remove information from the standard libraries */
/DISCARD/ :
{
libgcc.a ( * )
}
}